Zsh 安装配置

# Zsh 补全系统
mattmc3/ez-compinit                            # 加载 Zsh 补全系统
zsh-users/zsh-completions kind:fpath path:src  # 增强命令补全

# zephyr 套件补全 zsh 的默认配置
mattmc3/zephyr path:plugins/color       # 色彩相关
mattmc3/zephyr path:plugins/directory   # 目录操作
mattmc3/zephyr path:plugins/editor      # 编辑操作
mattmc3/zephyr path:plugins/environment # 环境变量相关
mattmc3/zephyr path:plugins/history     # 命令历史
mattmc3/zephyr path:plugins/utility     # 工具

# 集成 fzf 和 zoxide
ajeetdsouza/zoxide
Aloxaf/fzf-tab

# P10k 主题
romkatv/powerlevel10k

# 语法高亮和自动提示
zsh-users/zsh-autosuggestions                         # 自动提示
zsh-users/zsh-history-substring-search                # 历史搜索
zdharma-continuum/fast-syntax-highlighting kind:defer # 语法高亮 (延迟加载)

# P10k 即时提示
if [[ -r "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh" ]]; then
  source "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh"
fi

# ez-compinit配置: 开启补全系统缓存
# 路径优先级 $ZSH_COMPDUMP > $XDG_CACHE_HOME/zsh/zcompdump > ~/.cache/zsh/zcompdump
zstyle ':plugin:ez-compinit' 'use-cache' 'yes'

# ez-compinit配置: 使用oh-my-zsh 风格的补全
# 官方提供 styles: gremlin, ohmy, prez, zshzoo
# 只有 ohmy 预设与 fzf-tab 兼容, 其它模式 group 标题会有无法渲染的占位符
zstyle ':plugin:ez-compinit' 'compstyle' 'ohmy'

# zephyr配置: 启用和关闭一些 editor 预设功能
zstyle ':zephyr:plugin:editor' 'prepend-sudo' yes # 快捷键加 sudo 功能
zstyle ':zephyr:plugin:editor' 'pound-toggle' no  # 空格后显示别名原始形态
zstyle ':zephyr:plugin:editor' 'magic-enter' no   # 回车自动执行 ls 或 git 命令

# 配合 fzf-tab 相关补全选项
zstyle ':completion:*:git-checkout:*' sort false   # git-checkout 关闭按字母排序
zstyle ':completion:*:descriptions' format '[%d]'  # 窗口增加 group 标题

# fzf-tab 内部配置
zstyle ':fzf-tab:*' fzf-flags --bind=tab:accept                               # 使用 Tab 键确认 fzf-tab 中的选项
zstyle ':fzf-tab:complete:cd:*' fzf-preview 'eza -1 --color=always $realpath' # 在 cd 界面使用 eza 显示目录内容

# --- Antidote 启动部分 ---
# 官方推荐的高性能启动方式
zsh_plugins=${ZDOTDIR:-~}/.zsh_plugins
[[ -f ${zsh_plugins}.txt ]] || touch ${zsh_plugins}.txt
fpath=(/usr/share/zsh-antidote/functions $fpath)
autoload -Uz antidote
if [[ ! ${zsh_plugins}.zsh -nt ${zsh_plugins}.txt ]]; then
  antidote bundle <${zsh_plugins}.txt >|${zsh_plugins}.zsh
fi
source ${zsh_plugins}.zsh
# --- Antidote 启动结束 ---

# 启动 P10k 主题
[[ ! -f ~/.p10k.zsh ]] || source ~/.p10k.zsh

# 启动fzf-tab
enable-fzf-tab

# 修复 zephyr-directory 预设与补全系统的问题
# 防止操作目录命令的 Tab 选项中出现隐藏文件
unsetopt glob_dots

# 去掉 zephyr-editor 修改光标样式功能并恢复终端默认形态
function update-cursor-style { : }
printf '\e[0 q'

# --- 快捷键绑定 ---
# 绑定 Alt + S 为命令前增加 sudo
bindkey '\es' prepend-sudo

# 配置 zsh-history-substring-search 快捷键
bindkey '^[[A'   history-substring-search-up    2>/dev/null # '^[[A' 序列的上方向键
bindkey '^[OA'   history-substring-search-up    2>/dev/null # '^[[A' 序列的上方向键

bindkey '^[[B'   history-substring-search-down  2>/dev/null # '^[[B' 序列的下方向键
bindkey '^[OB'   history-substring-search-down  2>/dev/null # '^[OB' 序列的下方向键